Web codeur Developpement Web

(cible:DisplayObjectContainer).transform.perspectiveProjection.fieldOfView = 110;

(cible:DisplayObjectContainer).transform.perspectiveProjection.projectionCenter = new Point(200, 100);

package {
	import flash.display.Shape;
	import flash.display.Sprite;
	import flash.display.Stage;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.geom.Point;
	import flash.text.TextField;
	import flash.text.TextFormat;
 
	[SWF(width = 800, height = 600, backgroundColor = 0xFFFFFF, frameRate = 25)]
 
	/**
	 * Projection de perspective.
	 * Visualisation et modification du pointe fuite.
	 *
	 * @author Lorenzo
	 */
	public class Main extends Sprite {
		// ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
		// ——————————————————————————————————— Constructeur ——————————————————————————————————
		// ___________________________________________________________________________________
		public function Main():void {
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void {
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
			stage.scaleMode = "noScale";
 
			var tx:TextField = this.addChild(new TextField()) as TextField;
			tx.defaultTextFormat = new TextFormat("Courier New", 13, 0);
			tx.text = "Cliquer sur la scène pour modifier la position du point de fuite";
			tx.autoSize = "left";
			tx.mouseEnabled = false;
			tx.x = 5;
			tx.y = stage.stageHeight - tx.height;
 
			creerCercles();
 
			// valeur de l'angle du champ de vision
			this.transform.perspectiveProjection.fieldOfView = 110;
 
			stage.addEventListener(MouseEvent.MOUSE_DOWN, evtDebutProjection);
			stage.addEventListener(MouseEvent.MOUSE_UP, evtFinProjection);
		}
 
		// ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
		// ———————————————————————————— Gestionnaire d'évènements ————————————————————————————
		// ___________________________________________________________________________________
		private function evtDebutProjection(ev:MouseEvent):void {
			// annuler le click si l'objet sous la souris n'est pas le Stage
			if ( !(ev.target is Stage) ) return;
			modifierPointDeFuite(ev.stageX, ev.stageY);
			stage.addEventListener(MouseEvent.MOUSE_MOVE, evtProjection);
		} 
 
		private function evtProjection(ev:MouseEvent):void {
			modifierPointDeFuite(ev.stageX, ev.stageY);
		} 
 
		private function evtFinProjection(ev:MouseEvent):void {
			stage.removeEventListener(MouseEvent.MOUSE_MOVE, evtProjection);
		}
 
		// ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
		// ————————————————————————————— Déclaration des méthodes ————————————————————————————
		// ___________________________________________________________________________________
		/**
		 * modification de la position du point de fuite de la projection.
		 *
		 * @param	x
		 * @param	y
		 */
		private function modifierPointDeFuite(x:Number, y:Number):void {
			this.transform.perspectiveProjection.projectionCenter = new Point(x, y);
		}
		/**
		 * Création d'un cercle.
		 *
		 * @param	x
		 * @param	y
		 * @param	z
		 * @param	rayon
		 * @return
		 */
		private function creerCercle(x:Number, y:Number, z:Number, rayon:Number):Shape {
			var sh:Shape = new Shape();
			sh.graphics.lineStyle(0, 0, 0.2);
			sh.graphics.beginFill(Math.round(Math.random()*0xFF), 0.1);
			sh.graphics.drawCircle(0, 0, rayon);
			sh.graphics.endFill();
			sh.x = x;
			sh.y = y;
			sh.z = z;
			return sh;
		}
		/**
		 * Création des cercles.
		 * Les cercles sont tous alignés le centre de la scene (en x et y)
		 * mais ils sont décalés en z.
		 */
		private function creerCercles():void {
			var nbCercles:uint = 50;
			var decalageZ:uint = 50;
			// pour avoir 2 cercles au dessus de la scène et un autre au meme niveau
			// (permet de mieux visualiser les changements apportés par fieldOfView)
			var z:int = -decalageZ * 2;
 
			var x:Number = stage.stageWidth / 2;
			var y:Number = stage.stageHeight / 2;
			for (var i:uint = 0; i < nbCercles; i++, z += decalageZ) {
				this.addChild(creerCercle(x, y, z, 100));
			}
		}
 
	}
}